CREATE PROCEDURE asi_CreateOrRenamePK @tablename nvarchar(512), @columns nvarchar(512) AS
BEGIN
    DECLARE @keyName nvarchar(512)

    -- get the name of the table's Primary Key
    SELECT @keyName = name
      FROM sysobjects
     WHERE parent_obj = OBJECT_ID(@tablename)
       AND xtype = 'PK'

    -- if the key exists, but it not named according to our conventions, rename it
    IF @keyName IS NOT NULL AND @keyName <> ('PK_' + @tablename)
        EXEC ('sp_rename ''' + @keyName + ''', ''PK_' + @tablename + ''',''OBJECT''')

    -- if the key does not exist
    IF @keyName IS NULL
    BEGIN
        DECLARE @clustered nvarchar(12)
        SET @clustered = 'CLUSTERED'

        -- if a clustered index already exists, make this one non-clustered
        IF EXISTS (SELECT 1 FROM sysindexes where id = OBJECT_ID(@tablename) AND indid = 1)
            SET @clustered = 'NONCLUSTERED'

        -- add the key
        EXEC ('ALTER TABLE ' + @tablename + ' ADD CONSTRAINT PK_' + @tablename + ' PRIMARY KEY ' + @clustered +' (' + @columns + ')')
    END
END

GO